FM / aclocal

/usr/share/aclocal

Name	Size	Mode	Actions
bison-i18n.m4	1924	0644	edit dl rm
codeset.m4	842	0644	edit dl rm
dovecot-pigeonhole.m4	1895	0644	edit dl rm
extern-inline.m4	4368	0644	edit dl rm
fcntl-o.m4	4668	0644	edit dl rm
fontutil.m4	14160	0644	edit dl rm
freetype2.m4	6333	0644	edit dl rm
gettext.m4	15859	0644	edit dl rm
glibc2.m4	830	0644	edit dl rm
glibc21.m4	907	0644	edit dl rm
gpg-error.m4	4757	0644	edit dl rm
gpgrt.m4	4717	0644	edit dl rm
iconv.m4	9274	0644	edit dl rm
intdiv0.m4	2411	0644	edit dl rm
intl.m4	12120	0644	edit dl rm
intldir.m4	917	0644	edit dl rm
intlmacosx.m4	2533	0644	edit dl rm
intmax.m4	1123	0644	edit dl rm
inttypes-pri.m4	1253	0644	edit dl rm
inttypes_h.m4	1020	0644	edit dl rm
lcmessage.m4	1365	0644	edit dl rm
lib-ld.m4	3683	0644	edit dl rm
lib-link.m4	33059	0644	edit dl rm
lib-prefix.m4	8466	0644	edit dl rm
libgcrypt.m4	6237	0644	edit dl rm
libtool.m4	305862	0644	edit dl rm
libxml.m4	7881	0644	edit dl rm
libxslt.m4	8119	0644	edit dl rm
lock.m4	1463	0644	edit dl rm
longlong.m4	4739	0644	edit dl rm
ltargz.m4	2569	0644	edit dl rm
ltdl.m4	30030	0644	edit dl rm
ltoptions.m4	14514	0644	edit dl rm
ltsugar.m4	4384	0644	edit dl rm
ltversion.m4	699	0644	edit dl rm
lt~obsolete.m4	6140	0644	edit dl rm
mysql.m4	4221	0644	edit dl rm
nls.m4	1223	0644	edit dl rm
pkg.m4	12670	0644	edit dl rm
po.m4	18969	0644	edit dl rm
printf-posix.m4	1579	0644	edit dl rm
progtest.m4	3092	0644	edit dl rm
size_max.m4	3064	0644	edit dl rm
stdint_h.m4	995	0644	edit dl rm
threadlib.m4	15151	0644	edit dl rm
uintmax_t.m4	1113	0644	edit dl rm
visibility.m4	3351	0644	edit dl rm
wchar_t.m4	818	0644	edit dl rm
wint_t.m4	1053	0644	edit dl rm
xsize.m4	406	0644	edit dl rm

Edit: /usr/share/aclocal/longlong.m4 (4739B)

# longlong.m4 serial 17
dnl Copyright (C) 1999-2007, 2009-2016 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl From Paul Eggert.

# Define HAVE_LONG_LONG_INT if 'long long int' works.
# This fixes a bug in Autoconf 2.61, and can be faster
# than what's in Autoconf 2.62 through 2.68.

# Note: If the type 'long long int' exists but is only 32 bits large
# (as on some very old compilers), HAVE_LONG_LONG_INT will not be
# defined. In this case you can treat 'long long int' like 'long int'.

AC_DEFUN([AC_TYPE_LONG_LONG_INT],
[
  AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
  AC_CACHE_CHECK([for long long int], [ac_cv_type_long_long_int],
     [ac_cv_type_long_long_int=yes
      if test "x${ac_cv_prog_cc_c99-no}" = xno; then
        ac_cv_type_long_long_int=$ac_cv_type_unsigned_long_long_int
        if test $ac_cv_type_long_long_int = yes; then
          dnl Catch a bug in Tandem NonStop Kernel (OSS) cc -O circa 2004.
          dnl If cross compiling, assume the bug is not important, since
          dnl nobody cross compiles for this platform as far as we know.
          AC_RUN_IFELSE(
            [AC_LANG_PROGRAM(
               [[@%:@include <limits.h>
                 @%:@ifndef LLONG_MAX
                 @%:@ define HALF \
                          (1LL << (sizeof (long long int) * CHAR_BIT - 2))
                 @%:@ define LLONG_MAX (HALF - 1 + HALF)
                 @%:@endif]],
               [[long long int n = 1;
                 int i;
                 for (i = 0; ; i++)
                   {
                     long long int m = n << i;
                     if (m >> i != n)
                       return 1;
                     if (LLONG_MAX / 2 < m)
                       break;
                   }
                 return 0;]])],
            [],
            [ac_cv_type_long_long_int=no],
            [:])
        fi
      fi])
  if test $ac_cv_type_long_long_int = yes; then
    AC_DEFINE([HAVE_LONG_LONG_INT], [1],
      [Define to 1 if the system has the type 'long long int'.])
  fi
])

# Define HAVE_UNSIGNED_LONG_LONG_INT if 'unsigned long long int' works.
# This fixes a bug in Autoconf 2.61, and can be faster
# than what's in Autoconf 2.62 through 2.68.

# Note: If the type 'unsigned long long int' exists but is only 32 bits
# large (as on some very old compilers), AC_TYPE_UNSIGNED_LONG_LONG_INT
# will not be defined. In this case you can treat 'unsigned long long int'
# like 'unsigned long int'.

AC_DEFUN([AC_TYPE_UNSIGNED_LONG_LONG_INT],
[
  AC_CACHE_CHECK([for unsigned long long int],
    [ac_cv_type_unsigned_long_long_int],
    [ac_cv_type_unsigned_long_long_int=yes
     if test "x${ac_cv_prog_cc_c99-no}" = xno; then
       AC_LINK_IFELSE(
         [_AC_TYPE_LONG_LONG_SNIPPET],
         [],
         [ac_cv_type_unsigned_long_long_int=no])
     fi])
  if test $ac_cv_type_unsigned_long_long_int = yes; then
    AC_DEFINE([HAVE_UNSIGNED_LONG_LONG_INT], [1],
      [Define to 1 if the system has the type 'unsigned long long int'.])
  fi
])

# Expands to a C program that can be used to test for simultaneous support
# of 'long long' and 'unsigned long long'. We don't want to say that
# 'long long' is available if 'unsigned long long' is not, or vice versa,
# because too many programs rely on the symmetry between signed and unsigned
# integer types (excluding 'bool').
AC_DEFUN([_AC_TYPE_LONG_LONG_SNIPPET],
[
  AC_LANG_PROGRAM(
    [[/* For now, do not test the preprocessor; as of 2007 there are too many
         implementations with broken preprocessors.  Perhaps this can
         be revisited in 2012.  In the meantime, code should not expect
         #if to work with literals wider than 32 bits.  */
      /* Test literals.  */
      long long int ll = 9223372036854775807ll;
      long long int nll = -9223372036854775807LL;
      unsigned long long int ull = 18446744073709551615ULL;
      /* Test constant expressions.   */
      typedef int a[((-9223372036854775807LL < 0 && 0 < 9223372036854775807ll)
                     ? 1 : -1)];
      typedef int b[(18446744073709551615ULL <= (unsigned long long int) -1
                     ? 1 : -1)];
      int i = 63;]],
    [[/* Test availability of runtime routines for shift and division.  */
      long long int llmax = 9223372036854775807ll;
      unsigned long long int ullmax = 18446744073709551615ull;
      return ((ll << 63) | (ll >> 63) | (ll < i) | (ll > i)
              | (llmax / ll) | (llmax % ll)
              | (ull << 63) | (ull >> 63) | (ull << i) | (ull >> i)
              | (ullmax / ull) | (ullmax % ull));]])
])

cmd: