FM / api

/usr/src/kernels/4.18.0-553.157.1.el8_10.x86_64/scripts/coccinelle/api/

/usr/src/kernels/4.18.0-553.157.1.el8_10.x86_64/scripts/coccinelle/api

Name	Size	Mode	Actions
alloc/	-	0755	rm
debugfs/	-	0755	rm
check_bq27xxx_data.cocci	3504	0644	edit dl rm
drm-get-put.cocci	1532	0644	edit dl rm
d_find_alias.cocci	1309	0644	edit dl rm
err_cast.cocci	1097	0644	edit dl rm
kstrdup.cocci	2461	0644	edit dl rm
memdup.cocci	1350	0644	edit dl rm
memdup_user.cocci	1306	0644	edit dl rm
platform_no_drv_owner.cocci	3869	0644	edit dl rm
pm_runtime.cocci	2394	0644	edit dl rm
ptr_ret.cocci	1814	0644	edit dl rm
resource_size.cocci	2115	0644	edit dl rm
simple_open.cocci	1244	0644	edit dl rm
vma_pages.cocci	1519	0644	edit dl rm

Edit: /usr/src/kernels/4.18.0-553.157.1.el8_10.x86_64/scripts/coccinelle/api/resource_size.cocci (2115B)

///
/// Use resource_size function on resource object
/// instead of explicit computation.
///
//  Confidence: High
//  Copyright: (C) 2009, 2010 Nicolas Palix, DIKU.  GPLv2.
//  Copyright: (C) 2009, 2010 Julia Lawall, DIKU.  GPLv2.
//  Copyright: (C) 2009, 2010 Gilles Muller, INRIA/LiP6.  GPLv2.
//  URL: http://coccinelle.lip6.fr/
//  Options:
//
//  Keywords: resource_size
//  Version min: 2.6.27 resource_size
//

virtual context
virtual patch
virtual org
virtual report

//----------------------------------------------------------
//  For context mode
//----------------------------------------------------------

@r_context depends on context && !patch && !org@
struct resource *res;
@@

* (res->end - res->start) + 1

//----------------------------------------------------------
//  For patch mode
//----------------------------------------------------------

@r_patch depends on !context && patch && !org@
struct resource *res;
@@

- (res->end - res->start) + 1
+ resource_size(res)

//----------------------------------------------------------
//  For org mode
//----------------------------------------------------------

@r_org depends on !context && !patch && (org || report)@
struct resource *res;
position p;
@@

(res->end@p - res->start) + 1

@rbad_org depends on !context && !patch && (org || report)@
struct resource *res;
position p != r_org.p;
@@

res->end@p - res->start

@script:python depends on org@
p << r_org.p;
x << r_org.res;
@@

msg="ERROR with %s" % (x)
msg_safe=msg.replace("[","@(").replace("]",")")
coccilib.org.print_todo(p[0], msg_safe)

@script:python depends on report@
p << r_org.p;
x << r_org.res;
@@

msg="ERROR: Missing resource_size with %s" % (x)
coccilib.report.print_report(p[0], msg)

@script:python depends on org@
p << rbad_org.p;
x << rbad_org.res;
@@

msg="WARNING with %s" % (x)
msg_safe=msg.replace("[","@(").replace("]",")")
coccilib.org.print_todo(p[0], msg_safe)

@script:python depends on report@
p << rbad_org.p;
x << rbad_org.res;
@@

msg="WARNING: Suspicious code. resource_size is maybe missing with %s" % (x)
coccilib.report.print_report(p[0], msg)

cmd: